Chiziq bo‘ylab yuruvchi robot

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32

// motorlar (L298N)
const int ENA = 5, IN1 = 7, IN2 = 8;   // chap
const int ENB = 6, IN3 = 2, IN4 = 4;   // o‘ng

void motors(int left, int right) {     // -255 … 255
  digitalWrite(IN1, left >= 0);  digitalWrite(IN2, left < 0);
  digitalWrite(IN3, right >= 0); digitalWrite(IN4, right < 0);
  analogWrite(ENA, abs(left));   analogWrite(ENB, abs(right));
}

void setupMotors() {
  int pins[] = {ENA, IN1, IN2, ENB, IN3, IN4};
  for (int p : pins) pinMode(p, OUTPUT);
  motors(0, 0);
}

const int LEFT = 12, RIGHT = 11;   // HIGH = qora chiziq ustida
const int SPEED = 150, TURN = 170;

void setup() {
  setupMotors();
  pinMode(LEFT, INPUT); pinMode(RIGHT, INPUT);
  delay(1500);
}

void loop() {
  bool l = digitalRead(LEFT), r = digitalRead(RIGHT);
  if (!l && !r)      motors(SPEED, SPEED);    // chiziq sensorlar orasida
  else if (l && !r)  motors(-TURN / 2, TURN); // chiziq chap sensor ostida: chapga buriling
  else if (!l && r)  motors(TURN, -TURN / 2); // o‘ng sensor ostida: o‘ngga buriling
  else               motors(0, 0);            // ikkalasi qora: chorraha yoki marra
}