Цифровая рулетка

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

Adafruit_SSD1306 oled(128, 64, &Wire, -1);
const int TRIG = 12, ECHO = 11;

long readCm() {
  digitalWrite(TRIG, LOW);  delayMicroseconds(2);
  digitalWrite(TRIG, HIGH); delayMicroseconds(10);
  digitalWrite(TRIG, LOW);
  long us = pulseIn(ECHO, HIGH, 25000);
  return us ? us / 58 : -1;
}

// медиана пяти замеров: одно случайное эхо не испортит результат
long measure() {
  long r[5];
  for (int i = 0; i < 5; i++) { r[i] = readCm(); delay(15); }
  for (int i = 0; i < 4; i++)
    for (int j = i + 1; j < 5; j++)
      if (r[j] < r[i]) { long t = r[i]; r[i] = r[j]; r[j] = t; }
  return r[2];
}

void setup() {
  pinMode(TRIG, OUTPUT); pinMode(ECHO, INPUT);
  oled.begin(SSD1306_SWITCHCAPVCC, 0x3C);   // если экран не горит, попробуйте 0x3D
  oled.setTextColor(SSD1306_WHITE);
}

void loop() {
  long cm = measure();
  oled.clearDisplay();
  oled.setTextSize(1); oled.setCursor(0, 0);
  oled.print("Constell tape");
  oled.setTextSize(3); oled.setCursor(0, 22);
  if (cm < 2 || cm > 400) oled.print("---");
  else { oled.print(cm); oled.setTextSize(2); oled.print(" cm"); }
  oled.display();
  delay(150);
}